WITH main AS
(
SELECT 10 line_num, '' type FROM dual
UNION ALL SELECT  20, 'LINE'  FROM dual
UNION ALL SELECT  30, 'VALUE' FROM dual
UNION ALL SELECT  40, 'VALUE' FROM dual
UNION ALL SELECT  50, 'LINE'  FROM dual
UNION ALL SELECT  60, 'LINE'  FROM dual
UNION ALL SELECT  70, 'VALUE' FROM dual
UNION ALL SELECT  80, 'VALUE' FROM dual
UNION ALL SELECT  90, 'LINE'  FROM dual
UNION ALL SELECT 100, 'VALUE' FROM dual
)
, line AS
(
SELECT 20 line_num, '+' operator, 30 line_num_from, 30 line_num_to FROM dual
UNION ALL SELECT 20, '-',  40,  40 FROM dual
UNION ALL SELECT 50, '+',  20,  20 FROM dual
UNION ALL SELECT 50, '+',  90,  90 FROM dual
UNION ALL SELECT 60, '+',  80,  90 FROM dual
UNION ALL SELECT 60, '+',  90,  90 FROM dual
UNION ALL SELECT 90, '+', 100, 100 FROM dual    -- 요 라인이 누락된 듯?
)
, value AS
(
SELECT 30 line_num, '+' sign, 5 amt FROM dual
UNION ALL SELECT  40, '+', 20 FROM dual
UNION ALL SELECT  70, '+', 30 FROM dual
UNION ALL SELECT  80, '+', 40 FROM dual
UNION ALL SELECT 100, '-', 10 FROM dual
)
, tmp(line_num, sign, amt, line_num_from, line_num_to) AS
(
SELECT m.line_num
     , DECODE(l.operator, '-', -1, 1) * DECODE(v.sign, '-', -1, 1) sign
     , NVL(v.amt, 0) amt
     , l.line_num_from
     , l.line_num_to
  FROM main m
  LEFT OUTER JOIN line l
    ON m.type = 'LINE'
   AND m.line_num = l.line_num
  LEFT OUTER JOIN value v
    ON m.type = 'VALUE'
   AND m.line_num = v.line_num
 UNION ALL
SELECT p.line_num
     , p.sign * DECODE(l.operator, '-', -1, 1) * DECODE(v.sign, '-', -1, 1) sign
     , v.amt
     , l.line_num_from
     , l.line_num_to
  FROM tmp p
 INNER JOIN main m
    ON m.line_num BETWEEN p.line_num_from AND p.line_num_to
  LEFT OUTER JOIN line l
    ON m.type = 'LINE'
   AND m.line_num = l.line_num
  LEFT OUTER JOIN value v
    ON m.type = 'VALUE'
   AND m.line_num = v.line_num
)
SELECT line_num
     , SUM(sign * amt) amt
  FROM tmp
 GROUP BY line_num
 ORDER BY line_num
;

재귀 쿼리(Recursive SQL)입니다.
WITH 절에 선언된 tmp 를 WITH 절 안에서 사용하죠.(자기 참조, 재귀 호출)
UNION ALL 의 상단이 루트 레벨이고
UNION ALL 의 하단에서 계층 레벨을 늘려나가는 것입니다.
UNION ALL 의 하단 첫 수행시 tmp 에는 1레벨 정보가 담겨 있겠죠.
UNION ALL 의 하단 두번째 수행시에는 첫 수행 결과인 2레벨 정보가 담겨 있겠네요.
이렇게 차래대로 계층구조를 키워나가는 구문입니다.

-- 10G 용
SELECT line_num
     , SUM(sign * amt) amt
  FROM (SELECT CONNECT_BY_ROOT(m.line_num) line_num
             , DECODE(MOD(REGEXP_COUNT(
               SYS_CONNECT_BY_PATH(l.operator, ',')||v.sign
               , '-'), 2), 1, -1, 1) sign
             , NVL(v.amt, 0) amt
          FROM main m
          LEFT OUTER JOIN line l
            ON m.type = 'LINE'
           AND m.line_num = l.line_num
          LEFT OUTER JOIN value v
            ON m.type = 'VALUE'
           AND m.line_num = v.line_num
         WHERE CONNECT_BY_ISLEAF = 1
         CONNECT BY m.line_num BETWEEN PRIOR l.line_num_from AND PRIOR l.line_num_to
        )
 GROUP BY line_num
 ORDER BY line_num
;

우앙 이건 퀴즈로 나와도 재미있었겠네요~

seq 는 항상 10, 20 두가지만 존재한다고 봐도 될까요?

-- 1. 재귀함수 생성 --
CREATE OR REPLACE FUNCTION f_rec_test(v_line_num NUMBER)
RETURN NUMBER
IS
    v_ret1 NUMBER := 0;
    v_ret2 NUMBER := 0;
BEGIN
    BEGIN
        SELECT DECODE(sign, '-', -1, 1) * amt
          INTO v_ret1
          FROM value
         WHERE line_num = v_line_num
        ;
    EXCEPTION
        WHEN NO_DATA_FOUND THEN
            FOR c1 IN (SELECT *
                         FROM line l
                        WHERE l.line_num = v_line_num
                        ORDER BY seq
                       )
            LOOP
                v_ret2 := 0;
                FOR c2 IN (SELECT *
                             FROM main
                            WHERE line_num BETWEEN c1.line_num_from AND c1.line_num_to
                           )
                LOOP
                    v_ret2 := v_ret2 + f_rec_test(c2.line_num);
                END LOOP;
                IF c1.operator = '+' THEN
                    v_ret1 := v_ret1 + v_ret2;
                ELSIF c1.operator = '-' THEN
                    v_ret1 := v_ret1 - v_ret2;
                ELSIF c1.operator = '×' THEN
                    v_ret1 := v_ret1 * v_ret2;
                ELSIF c1.operator = '÷' THEN
                    v_ret1 := v_ret1 / v_ret2;
                ELSIF c1.operator = '%' THEN
                    v_ret1 := MOD(v_ret1, v_ret2);
                END IF;
            END LOOP;
    END;
    RETURN v_ret1;
END;
/

-- 2. 재귀함수 호출 --
SELECT line_num
     , f_rec_test(line_num) x
  FROM main
;

-- 1. 재귀함수 생성 --
CREATE OR REPLACE FUNCTION f_rec_test(v_line_num NUMBER, v_sign_flag VARCHAR2)
RETURN NUMBER
IS
    v_ret1 NUMBER := 0;
    v_ret2 NUMBER := 0;
BEGIN
    BEGIN
        SELECT DECODE(sign, '-', -1, 1) * amt
          INTO v_ret1
          FROM value
         WHERE line_num = v_line_num
        ;
    EXCEPTION
        WHEN NO_DATA_FOUND THEN
            FOR c1 IN (SELECT *
                         FROM line l
                        WHERE l.line_num = v_line_num
                        ORDER BY seq
                       )
            LOOP
                v_ret2 := 0;
                FOR c2 IN (SELECT *
                             FROM main
                            WHERE line_num BETWEEN c1.line_num_from AND c1.line_num_to
                           )
                LOOP
                    v_ret2 := v_ret2 + f_rec_test(c2.line_num);
                END LOOP;
                IF c1.operator = '+' THEN
                    v_ret1 := v_ret1 + v_ret2;
                ELSIF c1.operator = '-' THEN
                    v_ret1 := v_ret1 - v_ret2;
                ELSIF c1.operator = '×' THEN
                    v_ret1 := v_ret1 * v_ret2;
                ELSIF c1.operator = '÷' THEN
                    v_ret1 := v_ret1 / v_ret2;
                ELSIF c1.operator = '%' THEN
                    v_ret1 := MOD(v_ret1, v_ret2);
                END IF;
            END LOOP;
    END;
    IF v_sign_flag = 'Y' THEN
        v_ret1 := v_ret1 * -1;
    END IF;
    RETURN v_ret1;
END;
/

-- 2. 재귀함수 호출 --
SELECT line_num
     , f_rec_test(line_num, sign_flag) x
  FROM main
;

쿼리만으로는 여러가지 한계가 있어 함수 생성방법을 알려드린 것입니다.

지금의 상황에서 재귀함수가 딱 제격일 듯 한데요.